Groovy基礎文法最速マスター

print 'Hello, Groovy!!'        // 改行なし
println 'Hello, Groovy!!'      // 改行あり
printf 'Hello, %s', 'Groovy!!' // 整形して表示

// 一行コメント
/* 複数行コメント */
/** Groovydoc(Javadoc)コメント */

println("hi");
println("hi")
println "hi"

assert null == null
assert !(null == 1)

def a = 1      // => 実際の型はjava.lang.Integer (暗黙の型付け)
def b = 1.0f   // => 実際の型はjava.lang.Float   (暗黙の型付け)
int c = 1      // => 実際の型はjava.lang.Integer (Javaの基本型を使った明示的な型付け)
float d = 1    // => 実際の型はjava.lang.Float   (Javaの基本型を使った明示的な型付け)
Integer e = 1  // => 実際の型はjava.lang.Integer (参照型の型名を使った明示的な型付け)
String f = '1' // => 実際の型はjava.lang.String  (参照型の型名を使った明示的な型付け)

def str = 'シングルクォート'

def a = 'world'
def str1 = "hello $a"
def str2 = "hello ${a}"
assert str1 == str2
assert str1 == 'hello world'

def pathStr = /C:\temp\xxxx/  // バックスラッシュがそのまま使える
def regexpStr = /^\d{4}-\d{3}/  // 正規表現を宣言する時に便利
def color = 'blue'
def interpolatedSlashy = /a ${color} car/  // 変数埋め込みも可能

def pathStr = $/C:\temp\xxxx/$  // バックスラッシュがそのまま使える
def regexpStr = $/^\d{4}-\d{3}/$  // 正規表現を宣言する時に便利
def color = 'blue'
def interpolatedSlashy = $/a ${color} car/$  // 変数埋め込みも可能
def interpolatedSlashy2 = $/a $${color} car/$  // $でエスケープも可能

// シングルクォート文字列の複数バージョン
def multiStr1 = '''
これは
複数行の
文字列です。
'''

// シングルクォート文字列の複数バージョン
def multiStr2 = """
本日は
${new Date()}
なり。
"""

def color = 'blue'

// スラッシュ文字列
def multiStr3 = /
C:\temp\xxxx
^\d{4}-\d{3}
a ${color} car
/

// ドルスラッシュ文字列
def multiStr4 = $/
a ${color} car
a $${color} car
/$

assert true
assert !false

assert ('a' =~ /./)
assert !('a' =~ /b/)

assert [1]
assert ![]

assert ['a': 1]
assert ![:]

assert 'a'
assert !''

assert 1
assert 1.1
assert 1.2f
assert 1.3g
assert 2L
assert 3G
assert !0

assert new Object()
assert !null

assert '12345' =~ /\d+/
assert 'xxxxx' == '12345'.replaceAll(/\d/, 'x')

def roman = ['', 'I', 'II', 'III', 'IV', 'V', 'VI', 'VII'] // ローマ数字のリスト
assert roman[4] == 'IV' // リストへのアクセス
roman[8] = 'VIII' // リストの拡大
assert roman.size() == 9

def http = [
  100 : 'CONTINUE',
  200 : 'OK',
  400 : 'BAD REQUEST' ]
assert http[200] == 'OK'
http[500] = 'INTERNAL SERVER ERROR'
assert http.size() == 4

def x = 1..10
assert x.contains(5)
assert x.contains(15) == false
assert x.size() == 10
assert x.from == 1
assert x.to == 10
assert x.reverse() == 10..1
def y = 1..<10
assert y.from == 1
assert y.to == 9

[1, 2, 3].each { entry -> println entry }
[4, 5, 6].each { println it } // パラメータ省略時はitで参照できる
[a: 100, b: 200, c: 300].each { key, value ->
  println "${key}=${value}"
}

java.io.*
java.lang.*
java.math.BigDecimal
java.math.BigInteger
java.net.*
java.util.*
groovy.lang.*
groovy.util.*

class Book {    // クラスを宣言
  String title  // 型を明示的に指定してフィールドを宣言
  def prop      // defキーワードでフィールド宣言
  Book() {      // コンストラクタ
    // ...
  }
  int methodA(int p) { // 型を明示的に指定してメソッドを宣言
    // ...
  }
  void methodB(String p) { // 戻り値なしメソッド
    // ...
  }
  def methodC(p) { // defを使ってメソッドを宣言
    // ...
  }
  static def methodS() { // 静的メソッドを宣言
    // ...
  }
}

class Book {
  String title  // プロパティの宣言
}
def groovyBook = new Book()

// 明示的なメソッド呼び出しによるプロパティの利用
groovyBook.setTitle('Groovy world')
assert groovyBook.getTitle() == 'Groovy world'

// Groovyによるショートカットを使ったプロパティの利用
groovyBook.title = 'No Groovy, No Life'
assert groovyBook.title == 'No Groovy, No Life'